# gnuplot macro file for KEK watersystem log data (7-day shift data)
#
# rev. 1/16/01, HGB

# global settings:

# set pbm-format terminal emulation
set terminal pbm color small

# set plot size to 512x192 pixels
set size ratio 0.3 0.8,0.4

# plot grid lines
set grid

# x axis is time/date format as used in data file
set timefmt "%Y-%m-%d-%H:%M:%S"
set xdata time
set xlabel "   "
set format x "%m/%d\n%H:%M"

# define secondary x axis range for min/max labels and reference lines

set x2range [0:1]

# individual plots for each data column
#
# color codes for the line types (found out by experimenting):
# 0 = grey
# 1 = red
# 2 = green (light)
# 3 = blue
# 4 = light blue
# 5 = purple
# 6 = yellow
# 7 = brown
# 8 = dark green
# 9 = dark blue

max(x) = 1045
min(x) = 1025
set label 1 "max=1045" at second 0.01,1043.5 left
set label 2 "min=1025" at second 0.01,1026.0 left

set output "shift_01.pbm"
set title  "Water Level"
set ylabel "cm"
plot "wsys_7day.data" using 1:11 notitle w lp lt 8 pt 5, \
     max(x) axes x2y1 notitle w l lt 2, \
     min(x) axes x2y1 notitle w l lt 2

max(x) = 95
min(x) = 70
set label 1 "max=95" at second 0.01,94.0 left
set label 2 "min=70" at second 0.01,71.0 left

set output "shift_02.pbm"
set title  "Total Water Flow"
set ylabel "gallon per minute"
# set yrange [0:100]
plot "wsys_7day.data" using 1:26 notitle with fsteps lt 9, \
     max(x) axes x2y1 notitle w l lt 5, \
     min(x) axes x2y1 notitle w l lt 5

max(x) = 60
min(x) = 40
set label 1 "max=60" at second 0.01,59.0 left
set label 2 "min=40" at second 0.01,41.0 left

set output "shift_03.pbm"
set title  "Water Temperature (fill)"
set ylabel "Degrees Fahrenheit"
# set yrange [0:80]
plot "wsys_7day.data" using 1:21 notitle with fsteps lt 1, \
     max(x) axes x2y1 notitle w l lt 4, \
     min(x) axes x2y1 notitle w l lt 4

set output "shift_04.pbm"
set title  "Water Temperature (return)"
set ylabel "Degrees Fahrenheit"
# set yrange [0:80]
plot "wsys_7day.data" using 1:20 notitle with fsteps lt 1, \
     max(x) axes x2y1 notitle w l lt 4, \
     min(x) axes x2y1 notitle w l lt 4

max(x) = 20
min(x) = 15
set label 1 "max=20" at second 0.01,19.5 left
set label 2 "min=15" at second 0.01,15.5 left

set output "shift_05.pbm"
set title  "Water Resistance (after UV)"
set ylabel "MegOhms * cm"
# set yrange [0:20]
plot "wsys_7day.data" using 1:25 notitle with fsteps lt 7, \
     max(x) axes x2y1 notitle w l lt 6, \
     min(x) axes x2y1 notitle w l lt 6

max(x) = 15
min(x) = 5
set label 1 "max=15" at second 0.01,13.8 left
set label 2 "min=5" at second 0.01,6.2 left

set output "shift_06.pbm"
set title  "Water Resistance (return)"
set ylabel "MegOhms * cm"
# set yrange [0:20]
plot "wsys_7day.data" using 1:23 notitle with fsteps lt 7, \
     max(x) axes x2y1 notitle w l lt 6, \
     min(x) axes x2y1 notitle w l lt 6